// ColoredStorybook shader
// by guest(r)
// License: GNU-GPL

uniform sampler2D OGL2Texture;
uniform sampler2D OGL2TMU1;

void main()
{
	vec3 paper = texture2D(OGL2TMU1, gl_TexCoord[6].zw).xyz;
	vec3 c00 = texture2D(OGL2Texture, gl_TexCoord[5].xy).xyz; 
	vec3 c10 = texture2D(OGL2Texture, gl_TexCoord[1].xy).xyz; 
	vec3 c20 = texture2D(OGL2Texture, gl_TexCoord[2].zw).xyz; 
	vec3 c01 = texture2D(OGL2Texture, gl_TexCoord[3].xy).xyz; 
	vec3 c11 = texture2D(OGL2Texture, gl_TexCoord[0].xy).xyz; 
	vec3 c21 = texture2D(OGL2Texture, gl_TexCoord[4].xy).xyz; 
	vec3 c02 = texture2D(OGL2Texture, gl_TexCoord[1].zw).xyz; 
	vec3 c12 = texture2D(OGL2Texture, gl_TexCoord[2].xy).xyz; 
	vec3 c22 = texture2D(OGL2Texture, gl_TexCoord[6].xy).xyz; 
	vec3 dt = vec3(1.0,1.0,1.0); 

	c11 = 0.25*(c11+0.5*(c10+c01+c12+c21)+0.25*(c02+c20+c00+c22));

	float d1=dot(abs(c00-c22),dt)/(dot(c00+c22,dt)+0.50);
	float d2=dot(abs(c20-c02),dt)/(dot(c20+c02,dt)+0.50);
	float hl=dot(abs(c01-c21),dt)/(dot(c01+c21,dt)+0.50);
	float vl=dot(abs(c10-c12),dt)/(dot(c10+c12,dt)+0.50);
	float d=d1+d2+hl+vl;

	d =  0.5*pow(d,0.5) + d;
	c11 = (1.0-0.6*d)*c11;

	gl_FragColor.xyz = mix(paper, c11, pow(max(min(d,1.1)-0.1,0.0),0.5));
}
